;-----------------------------------------------------------
;
;	8 SW --> MIDI, MIDI --> 192 LEDs : November 2007
;
;		for IC2007 Yamada Mayumi
;
;-----------------------------------------------------------

;##### Port Defines #####
smr	.equ	h'0fffb0
brr	.equ	h'0fffb1
scr	.equ	h'0fffb2
tdr	.equ	h'0fffb3
ssr	.equ	h'0fffb4
rdr	.equ	h'0fffb5
p1ddr	.equ	h'0fffc0
p1dr	.equ	h'0fffc2
p2ddr	.equ	h'0fffc1
p2dr	.equ	h'0fffc3
p3ddr	.equ	h'0fffc4
p3dr	.equ	h'0fffc6
paddr	.equ	h'0fffd1
padr	.equ	h'0fffd3
pbddr	.equ	h'0fffd4
pbdr	.equ	h'0fffd6
iprb	.equ	h'0ffff8

;##### Vector Defines #####
	.section vector,data,locate=h'000000
	.data.l	start
	.org	h'0000d0
	.data.l	int_rx_error
	.data.l	int_rx_full

;##### Work RAM Data Defines #####
	.section ram,data,locate=h'0fef10
timer1	.res.w	1
timer2	.res.w	1
timer3	.res.w	1
tx_top	.res.w	1
tx_end	.res.w	1
rx_top	.res.w	1
rx_end	.res.w	1
data574	.res.b	24
rsb	.res.b	1
channel	.res.b	1
dcb	.res.b	1
keyno	.res.b	1
data	.res.b	1
old_sw	.res.b	1
latchNO	.res.b	1
portsel	.res.b	1
latch_d	.res.b	1
latch_p	.res.b	1
	.org	h'0ff400
rx_fifo	.res.b	1024
	.org	h'0ff800
tx_fifo	.res.b	1024

;***** Reset --> Initialize --> Main Loop *****
	.section program,code,locate=h'001000
start:
	mov.l	#h'0fff0f,er7		; stack pointer set
	mov.l	#h'0fef10,er2
	mov.w	#h'0fe0,r1
	mov.b	#0,r0l
_ram_clear:
	mov.b	r0l,@er2
	inc.l	#1,er2
	dec.w	#1,r1
	bne	_ram_clear
	jsr	@sci0_init		; SCI initialize
	mov.b	#b'00000000,r0l
	mov.b	r0l,@pbddr		; set : Port[B] all input
	mov.b	#b'11111111,r0l
	mov.b	r0l,@p1ddr		; set : Port[1] all output
	mov.b	r0l,@p2ddr		; set : Port[2] all output
	mov.b	r0l,@p3ddr		; set : Port[3] all output
	mov.b	r0l,@paddr		; set : Port[A] all output
	mov.b	#0,r0l
	mov.w	#0,r2
	mov.w	#0,e2
	mov.b	#24,r1h
_set_ini:
	mov.b	r0l,@(data574,er2)
	inc.w	#1,r2
	dec.b	r1h
	bne	_set_ini
	jsr	@led_all_off
	jsr	@wait_500msec
	mov.b	@pbdr,r1h
	mov.b	r1h,@old_sw
	mov.b	#b'01110000,r0l		; tx/rx start !
	mov.b	r0l,@scr
	andc.b	#b'01111111,ccr		; interrupt enable
loop:
	jsr	@timer_check
	jsr	@tx_midi_check
	jsr	@rx_midi_check
	bra	loop

;***** Common Sub-Routines *****
sci0_init:
	mov.b	#b'00000000,r0l
	mov.b	r0l,@scr
	mov.b	#b'00000000,r0l
	mov.b	r0l,@smr
	mov.b	#15,r0l
	mov.b	r0l,@brr
	mov.w	#500,r0
_sci0_wait:
	dec.w	#1,r0
	bne	_sci0_wait
	mov.b	@ssr,r0l		; (dummy read)
	mov.b	#0,r0l
	mov.b	r0l,@ssr
	mov.b	#b'00001000,r0l
	mov.b	r0l,@iprb		; SCI0-int priority UP !
	rts
int_rx_error:
	bclr	#5,@ssr
	bclr	#4,@ssr
	rte
int_rx_full:
	push.w	r0
	push.l	er5
	btst	#6,@ssr
	bclr	#6,@ssr
	mov.w	@rx_top,r5
	mov.w	#0,e5
	mov.b	@rdr,r0l
	mov.b	r0l,@(rx_fifo,er5)
	inc.w	#1,r5
	bclr	#2,r5h
	mov.w	r5,@rx_top
	pop.l	er5
	pop.w	r0
	rte
tx_midi_check:
	mov.w	@tx_top,r1
	mov.w	@tx_end,r6
	cmp.w	r1,r6
	bne	_tx_exist
	rts
_tx_exist:
	btst	#7,@ssr			; test TRDE
	bne	_tx_seq
	rts
_tx_seq:
	mov.w	#0,e6
	mov.b	@(tx_fifo,er6),r0l
	mov.b	r0l,@tdr
	bclr	#7,@ssr			; Transmit !
	inc.w	#1,r6
	bclr	#2,r6h
	mov.w	r6,@tx_end
	rts
tx_fifo_set:
	mov.w	@tx_top,r6
	mov.w	#0,e6
	mov.b	r0h,@(tx_fifo,er6)	; transmit data = [r0h]
	inc.w	#1,r6
	bclr	#2,r6h
	mov.w	r6,@tx_top
	rts
wait_500msec:
	mov.l	#500,er1
_wait_1:
	jsr	@wait_1msec
	sub.l	#1,er1
	bne	_wait_1
	rts
wait_1msec:
	mov.l	#2048,er2
_wait_2:
	sub.l	#1,er2
	bne	_wait_2
	rts

timer_check:
	mov.w	@timer1,r1
	inc.w	#1,r1
	mov.w	r1,@timer1
	mov.w	@timer1,r1
	cmp.w	#20000,r1
	beq	_timer_1
	rts
_timer_1:
	mov.w	#0,r1
	mov.w	r1,@timer1
	mov.b	@pbdr,r1h		; [R1H] current sensor status
	mov.b	@old_sw,r2h		; [R2H] old sensor status
	cmp.b	r1h,r2h
	bne	_sensor_event
	rts
_sensor_event:
	mov.b	r1h,@old_sw		; renew status buffer
	xor.b	r1h,r2h			; [R2H] event bits
	mov.b	#b'00000001,r3h		; [R3H] bit mask
	mov.b	#0,r3l			; loop counter
_sensor_loop:
	mov.b	r3h,r0l
	and.b	r2h,r0l			; event ?
	beq	_sensor_2
	mov.b	#h'90,r0h
	jsr	@tx_fifo_set
	mov.b	r3l,r0h
	add.b	#60,r0h
	jsr	@tx_fifo_set
	mov.b	r3h,r0l
	and.b	r1h,r0l			; ON/OFF ?
	beq	_sensor_on
	bra	_sensor_off
_sensor_on:
	mov.b	#127,r0h
	bra	_sensor_go
_sensor_off:
	mov.b	#0,r0h
_sensor_go:
	jsr	@tx_fifo_set
_sensor_2:
	shll.b	r3h
	inc.b	r3l
	cmp.b	#8,r3l
	bne	_sensor_loop
	rts
led_all_off:
	mov.b	#b'11111111,r0l
	mov.b	r0l,@padr
	mov.b	r0l,@p1dr
	mov.b	r0l,@p2dr
	mov.b	r0l,@p3dr
	nop
	mov.b	#b'00000000,r0l
	mov.b	r0l,@p1dr
	mov.b	r0l,@p2dr
	mov.b	r0l,@p3dr
	nop
	mov.b	#b'11111111,r0l
	mov.b	r0l,@p1dr
	mov.b	r0l,@p2dr
	mov.b	r0l,@p3dr
	rts

;***** MIDI Receive Routine *****
rx_midi_check:
	mov.w	@rx_top,r1
	mov.w	@rx_end,r5
	cmp.w	r1,r5
	bne	_rx_exist
	rts
_rx_exist:
	mov.w	#0,e5
	mov.b	@(rx_fifo,er5),r0h	; received data = [r0h]
	inc.w	#1,r5
	bclr	#2,r5h
	mov.w	r5,@rx_end
	btst	#7,r0h
	beq	running
	mov.b	r0h,r0l
	and.b	#b'11111000,r0l
	cmp.b	#b'11111000,r0l
	bne	_lower_f8
	rts
_lower_f8:
	and.b	#b'11110000,r0l
	cmp.b	#b'11110000,r0l
	bne	_lower_f0
	mov.b	#0,r0l
	mov.b	r0l,@rsb
	rts
_lower_f0
	mov.b	r0h,r0l
	and.b	#b'00001111,r0l
	mov.b	r0l,@channel
	mov.b	r0h,r0l
	and.b	#b'11110000,r0l
	mov.b	r0l,@rsb
	mov.b	#0,r0l
	mov.b	r0l,@dcb
	rts
running:
	mov.b	@rsb,r0l
	bne	_normal
	rts
_normal:
	cmp.b	#b'11000000,r0l
	beq	_2byte
	cmp.b	#b'11010000,r0l
	beq	_2byte
	mov.b	@dcb,r1l
	bne	_3byte
	inc.b	r1l
	mov.b	r1l,@dcb
	mov.b	r0h,@keyno
	rts
_2byte:
	rts
_3byte:
	mov.b	#0,r1h
	mov.b	r1h,@dcb
;	mov.b	r0h,@data
	mov.b	@rsb,r0l
	cmp.b	#h'90,r0l
	beq	_note_on
	cmp.b	#h'80,r0l
	beq	_note_off
	rts
_note_on:
	cmp.b	#0,r0h
	beq	_note_off
	jsr	@address_set
	mov.b	@latchNO,r2l
	mov.b	#0,r2h
	mov.w	#0,e2
	mov.b	@(data574,er2),r0l	; get Latch(0-23) data
	mov.b	@latch_d,r1h
	or.b	r1h,r0l
	mov.b	r0l,@(data574,er2)	; 245 ON data
	jsr	@latch_write
	rts
_note_off:
	jsr	@address_set
	mov.b	@latchNO,r2l
	mov.b	#0,r2h
	mov.w	#0,e2
	mov.b	@(data574,er2),r0l	; get Latch(0-23) data
	mov.b	@latch_d,r1h
	xor.b	#b'11111111,r1h
	and.b	r1h,r0l
	mov.b	r0l,@(data574,er2)	; 245 OFF data
	jsr	@latch_write
	rts

latch_write
	xor.b	#b'11111111,r0l
	mov.b	r0l,@padr		; 245 -> 574 Data Line
	mov.b	@latch_p,r2h
	mov.b	@portsel,r0l
	cmp.b	#0,r0l
	beq	_port_P1
	cmp.b	#1,r0l
	beq	_port_P2
	cmp.b	#2,r0l
	beq	_port_P3
	rts
_port_P1:
	mov.b	r2h,@p1dr
	mov.b	#b'11111111,r0l
	mov.b	r0l,@p1dr
	rts
_port_P2:
	mov.b	r2h,@p2dr
	mov.b	#b'11111111,r0l
	mov.b	r0l,@p2dr
	rts
_port_P3:
	mov.b	r2h,@p3dr
	mov.b	#b'11111111,r0l
	mov.b	r0l,@p3dr
	rts

address_set:
	mov.b	@channel,r0l
	and.b	#b'00000011,r0l
	mov.b	#6,r1h
	mulxu.b	r1h,r0			; R0L = 6 * CH
	mov.b	@keyno,r1l
	mov.b	r1l,r2h
	shlr.b	r1l
	shlr.b	r1l
	shlr.b	r1l
	add.b	r1l,r0l
	mov.b	r0l,@latchNO		; Latch No. 0-23
	mov.b	r0l,r3h
	shlr.b	r0l
	shlr.b	r0l
	shlr.b	r0l
	mov.b	r0l,@portsel		; 0=P1, 1=P2, 2=P3
	mov.b	#b'00000001,r1h
	and.b	#b'00000111,r2h		; KeyNo % 8
_add_loop:
	cmp.b	#0,r2h
	beq	_add_exit
	shll.b	r1h
	dec.b	r2h
	bra	_add_loop
_add_exit:
	mov.b	r1h,@latch_d		; Latch data - bit pattern
	mov.b	#b'00000001,r1h
	and.b	#b'00000111,r3h		; LatchNo % 8
_add_loop2:
	cmp.b	#0,r3h
	beq	_add_exit2
	shll.b	r1h
	dec.b	r3h
	bra	_add_loop2
_add_exit2:
	xor.b	#b'11111111,r1h
	mov.b	r1h,@latch_p		; Port Latch Pulse
	rts

	.end